Scripting a Popup Shortcut

from Stardock Forums
I have seen several articles explaining methods for scripting a shortcut for an object. Could anyone suggest a method allowing the scripted shortcut to be opened as a folder shortcut popup menu?

I would use the object properties for this except that I don't want the object to react as a shortcut every time files are dragged to it.
desktopx
11,670 views 21 replies
Reply #1 from WinCustomize Forums Top
Depending on what your doing, why not use the "shortcut" object type?

Under the General tab select change beside "Object Type"
Choose shortcut in drop list box
Choose Folder
Check the Menu Location
Reply #2 from Stardock Forums Top
Thanks for the suggestion, however that doesn't seem to work for my application:


"I would use the object properties for this except that I don't want the object to react as a shortcut every time files are dragged to it."

-Let's say that you were creating an object titled "Drop Files Here to Create a Shortcut". The first time a file or folder was dropped ont the object its path is used to set the object's shortcut. After that you want the object to act as a shortcut to that file or folder using the popup folder.

If you use the "shortcut" object type it acts as a shortcut all the time, even if you set the shortcut path to "" it will default to "My Computer". The first time you drop a file on the object it gets sent to the defalut shortcut. This sets up an interesting Catch 22 situation; the object shortcut was set with path of the file when it was dropped but the object moved the file to the object's default path then set the object path to where the file used to be so the new shortcut is always invalid.

Would you know of any way to set the "object type" from the script?

-Dave-
Start11 - Customize the Start Menu and Taskbar in Windows 10/11.
Reply #3 from WinCustomize Forums Top
I think you'd have to create your own r-click menu listing the contents of the target folder.

The basic concept is to drag and drop a folder, get the contents of the folder, put them in an array, and use the array to build a custom r-click menu.

I was working on something similar, and I think with a little tweaking it could be achieved.

Reply #4 from WinCustomize Forums Top
Alrighty, this was pieced together from some of scripts I've saved. This goes into the one object. It will take one file or folder. If it's a file it'll open it on l-click. If it's a folder it will show a pop-up menu on l-click.


Code: vbscript
  2. Dim fso, fname(), fpath()
  4. 'Called when the script is executed
  5. Sub Object_OnScriptEnter
  6. Set fso = CreateObject("Scripting.FileSystemObject")
  7. End Sub
  9. 'Called when the script is terminated
  10. Sub Object_OnScriptExit
  12. End Sub
  14. 'Called when files are dropped onto object
  15. Sub Object_OnDropFiles(files)
  16. 'Get the first file dropped
  17. If Instr(files, "|") > 0 Then
  18. fArray = Split(files, "|")
  19. f1 = LBound(fArray)
  20. Else
  21. f1 = files
  22. End If
  23. 'If folder, call function to get contents
  24. If fso.GetExtensionName(f1) = "" Then
  25. Object.ToolTipText = fso.GetBaseName(f1)'--Set tooltip to foldername
  26. GetFolderContents(f1)
  27. 'If file, set arrays, tooltip to file name
  28. Else
  29. ReDim Preserve fname(0), fpath(0)
  30. fname(0) = fso.GetBaseName(f1)
  31. Object.ToolTipText = fso.GetBaseName(f1)
  32. fpath(0) = f1
  33. End If
  34. End Sub
  36. Function GetFolderContents(fldr)
  37. ReDim fname(-1), fpath(-1)
  38. Set f = fso.GetFolder(fldr)
  39. Set fl = f.Subfolders
  40. Set fi = f.files
  41. '--Get subfolders
  42. For Each elem In fl
  43. ReDim Preserve fname(UBound(fname)+1)
  44. ReDim Preserve fpath(UBound(fpath)+1)
  45. fname(UBound(fname)) = fso.GetFileName(elem)
  46. fpath(UBound(fpath)) = fso.GetAbsolutePathName(elem)
  47. Next
  48. '--Get files
  49. For Each elem In fi
  50. ReDim Preserve fname(UBound(fname)+1)
  51. fname(UBound(fname)) = fso.GetFileName(elem)
  52. ReDim Preserve fpath(UBound(fpath)+1)
  53. fpath(UBound(fpath)) = fso.GetAbsolutePathName(elem)
  54. Next
  55. End Function
  57. Function Object_OnLButtonUpEx(obj,x,y,dragged)
  58. If Not dragged Then
  59. '--If folder, show pop up menu
  60. If UBound(fname) > 0 Then
  61. Call CreateSectionMenu()
  62. '--If file, open file
  63. Else
  64. On Error Resume Next
  65. Set Sh = CreateObject("WScript.Shell")
  66. target = fpath(0)
  67. Sh.Run (Chr(34)& target & Chr(34))
  68. Set Sh = Nothing
  69. End If
  70. End If
  71. End Function
  73. Sub CreateSectionMenu()
  74. Set mainmenu = nothing
  75. Set mainmenu = DesktopX.CreatePopupMenu
  76. Set submenu= DesktopX.CreatePopupMenu
  77. For x = 0 To UBound(fname)
  78. mainmenu.AppendMenu 0, x+1, fname(x)
  79. Next
  80. result = mainmenu.TrackPopupMenu(0, System.CursorX, System.CursorY)
  81. Call ExecuteSectionMenu(result,snum)
  82. End Sub
  85. Sub ExecuteSectionMenu(result,snum)
  86. If result > 0 Then
  87. On Error Resume Next
  88. Set Sh = CreateObject("WScript.Shell")
  89. target = fpath(result-1)
  90. Sh.Run (Chr(34)& target & Chr(34))
  91. Set Sh = Nothing
  92. End If
  93. End Sub


Let me know if this is what you're looking for.
Reply #5 from WinCustomize Forums Top
Cool!
Reply #6 from WinCustomize Forums Top
Thanks, Zubaz.
Reply #7 from WinCustomize Forums Top
Cool!
End of quote


Yes, yes she is!

Um you might want to add a line under the Left Click Function
in order to suppress a subscript error if no item has been dropped.

Like This
Code: vbscript
  2. Function Object_OnLButtonUpEx(obj,x,y,dragged)
  3. If Not dragged Then
  4. On Error Resume Next 'Add here
  5. '--If folder, show pop up menu
  6. If UBound(fname) > 0 Then
  7. Call CreateSectionMenu()
  8. '--If file, open file
  9. Else
  10. On Error Resume Next
  11. Set Sh = CreateObject("WScript.Shell")
  12. target = fpath(0)
  13. Sh.Run (Chr(34)& target & Chr(34))
  14. Set Sh = Nothing
  15. End If
  16. End If
  17. End Function


If your heart is set on the same menu style as the default folder menu's then I have an idea but, it would involve three objects.
Reply #8 from WinCustomize Forums Top
you might want to add a line under the Left Click Function
End of quote


Perfect! Thanks SirS.
Reply #9 from Stardock Forums Top
Wow, thanks everybody. This is really good stuff.

sViz, thanks for the fso script, that gives me an idea....


SirSmiley, yes, I am somewhat attached to the to the default folder menu since it allows for a unique browsing experience -the folders show up as folder icons and open automatically on mouse over. What is your idea?
Reply #10 from WinCustomize Forums Top
Okay, here goes.

Create three objects called objBase, objFile, objFolder respectively.
objFile should be set up as a file shortcut object.
objFolder should be set up as a Folder Shortcut Object. *Make sure you check the menu option.

Set objFile & objFolder as child objects of objBase and set both to not visible. Everything will be controlled from the main script in the base object.

Here's the script.

Code: vbscript
  2. Const oBase = "objBase"
  3. Const oFile = "objFile"
  4. Const oFldr = "objFolder"
  6. '1 for File|2 for Folder
  7. Dim oCommand
  9. Set oFSO = CreateObject("Scripting.FileSystemObject")
  11. 'Called when a file is dropped onto object
  12. Function Object_OnDropFiles(files)
  13. 'Makes sure only one file or folder is dropped
  14. If Instr(files, "|") = 0 Then
  15. If oFSO.GetExtensionName(files) = "" Then
  16. DesktopX.Object(oFldr).Command=files
  17. oCommand=2
  18. Else
  19. DesktopX.Object(oFile).Command=files
  20. oCommand=1
  21. End If
  22. Else
  23. msgbox "You must drop only 1 file or folder"
  24. End If
  25. End Function
  27. Function Object_OnLButtonUpEx(obj,x,y,dragged)
  28. If Not dragged Then
  29. If oCommand="" Then
  30. msgbox "Please drop a file or folder first"
  31. 'Excutes objFile Command
  32. ElseIf oCommand = 1 Then
  33. DesktopX.Object(oFile).ExecuteCommand
  34. 'Executes objFolder Command
  35. ElseIf oCommand = 2 Then
  36. DesktopX.Object(oFldr).ExecuteCommand
  37. End If
  38. End If
  39. End Function
Reply #11 from WinCustomize Forums Top
I'll bet that if I paid more attention I could learn a bunch.  Until then . . I'l just copy and paste what I need. 
Thanks for the effort all.  It rocks how the DX (sub) community shares knowledge.
Reply #12 from WinCustomize Forums Top
I'll bet that if I paid more attention I could learn a bunch.
End of quote


Same here!
Reply #13 from WinCustomize Forums Top
Oh, I forgot one thing. Before I went away last week I made a drop script based menu bar for my usb drive.

The above script doesn't work when compiled to a gadget; so, I'm not sure how it will work in widgets or themes. I used an ini file but, persiststorage most likely will be the easiest way.

Here's a script that uses persiststorage. Notice the additional function.

Code: vbscript
  2. Const oBase = "objBase"
  3. Const oFile = "objFile"
  4. Const oFldr = "objFolder"
  6. '1 for File|2 for Folder
  7. Dim oCommand
  9. Set oFSO = CreateObject("Scripting.FileSystemObject")
  11. 'Called when a file is dropped onto object
  12. Function Object_OnDropFiles(files)
  13. 'Makes sure only one file or folder is dropped
  14. If Instr(files, "|") = 0 Then
  15. 'Saves dropped file/folder into a persist storage variable
  16. Object.PersistStorage("objShortcut") = files
  17. Else
  18. msgbox "You must drop only 1 file or folder"
  19. End If
  20. Call filefldrCheck
  21. End Function
  23. Function filefldrCheck
  24. 'Loads "objShortuct" Persist Storage variable
  25. oShorcut=Object.PersistStorage("objShortcut")
  26. If oFSO.GetExtensionName(oShorcut) = "" Then
  27. DesktopX.Object(oFldr).Command=oShorcut
  28. DesktopX.Object(oBase).ToolTipText=oFSO.GetBaseName(oShorcut)
  29. oCommand=2
  30. Else
  31. DesktopX.Object(oFile).Command=oShorcut
  32. DesktopX.Object(oBase).ToolTipText=oFSO.GetBaseName(oShorcut)
  33. oCommand=1
  34. End If
  35. End Function
  38. Function Object_OnLButtonUpEx(obj,x,y,dragged)
  39. If Not dragged Then
  40. If oCommand="" Then
  41. msgbox "Please drop a file or folder first"
  42. 'Excutes objFile Command
  43. ElseIf oCommand = 1 Then
  44. DesktopX.Object(oFile).ExecuteCommand
  45. 'Executes objFolder Command
  46. ElseIf oCommand = 2 Then
  47. DesktopX.Object(oFldr).ExecuteCommand
  48. End If
  49. End If
  50. End Function
Reply #14 from WinCustomize Forums Top
I'll bet that if I paid more attention I could learn a bunch.


Same here
End of quote
Ummm . . dude . . I was talking about learnign from you too. 
Reply #15 from WinCustomize Forums Top
Too cool, SirS. I was having some trouble setting the correct folder location OnDrop because the target was originally set to one of the preset folders. After I browsed for and set it to a different location it worked perfectly. This script is a keeper!


It rocks how the DX (sub) community shares knowledge.
End of quote


Agreed! I learn something new everyday. Gotta love this place.
Reply #16 from WinCustomize Forums Top
Yeah, I've got everyone fooled!

It looks complex but, if you've worked with statements/formulas in Excel it's just a matter of finding things in the DesktopX Documentation and the WSH SDK Help File.

Edit: SViz, yeah I had that problem with the menu bar gadget. Probably best to set the command object to a null value in the Exit Script if it appears again.

Oh! One more thing if you're using the Persist Storage Script then maybe put the Call filefldrCheck into the OnScriptEnter Sub.
Reply #17 from WinCustomize Forums Top
Really Nice Scripts.
Reply #18 from Stardock Forums Top

Again, Wow! Thanks for all the help, I'm learning a lot.

SirSmiley, This is very close to the approach I tried except that I had no File System Object script (this is much neater) and I only used a foder object child (didn't think about the file shortcut being different) and I did a poor job at checking for errors ...and it took me a month to figure out. Other than that it's identical :)

Now for the tricky part: Lets say that after you drop a folder the object goes from "Drop Files Here to Create a Shortcut" to "I am a shortcut to the folder you just dropped on me" and now allows drag and drop to the shortcut set in "objFldr". Since the object is a child of "objBase", files that are dropped on the parent don't make it to the child. Is there a way to either pass the dropped file through to the child or promote the child to the parent?

Thanks,

-Dave-
Reply #19 from WinCustomize Forums Top
Was about to say you really don't need the file object but, then it sort of depends on your needs. If you want to use command parameters it makes it simple but, that can also be scripted.

To answer your question really depends on a few things but, I'm assuming you want the ability for the shortcut to be dynamic? So, I scripted that into a right click function.
You need to set the objFldr object Activation to visible area and set the transparency to 0 then still set visibility to no and make sure it's the same size as the base object.

Oh, last night I scripted in the ability to change the base object to a png or ico image. You should also note that this script doesn't clean out persist storage cache;so, if you reset it then don't drop anything it will call the settings on the next load.

Code: vbscript
  2. Const oBase = "objBase"
  3. Const oFile = "objFile"
  4. Const oFldr = "objFolder"
  6. '1 for File|2 for Folder
  7. Dim oCommand
  8. 'Object.Command and Object.CommandParams
  9. 'Object.ExecuteCommand
  10. 'Object.PersistStorage
  11. 'Object.Command = "c:\program files\Internet Explorer\iexplore.exe"
  12. 'Object.CommandParams = "https://www.wincustomize.com"
  14. 'Called when a file is dropped onto object
  15. Function Object_OnDropFiles(files)
  16. 'Makes sure only one file or folder is dropped
  17. If Instr(files, "|") = 0 Then
  18. Set oFSO = CreateObject("Scripting.FileSystemObject")
  19. 'Checks to see if dropped item is an image file for the icon
  20. oDropItem=oFSO.GetExtensionName(files)
  21. If oDropItem = "ico" Or oDropItem = "png" Then
  22. DesktopX.Object(oBase).Picture = files
  23. Object.PersistStorage("objIcon")=files
  24. Else
  25. 'Saves dropped file/folder into a persist storage variable
  26. Object.PersistStorage("objShortcut") = files
  27. End If
  28. Else
  29. msgbox "You must drop only 1 file or folder"
  30. End If
  31. Call filefldrCheck
  32. End Function
  34. 'Called on Left Click Up
  35. Function Object_OnLButtonUpEx(obj,x,y,dragged)
  36. If Not dragged Then
  37. Select Case obj.name
  38. Case "oBase"
  39. If oCommand="" Then
  40. msgbox "Please drop a file or folder first"
  41. 'Excutes objFile Command
  42. ElseIf oCommand = 1 Then
  43. DesktopX.Object(oFile).ExecuteCommand
  44. 'Executes objFolder Command
  45. ElseIf oCommand = 2 Then
  46. DesktopX.Object(oFldr).ExecuteCommand
  47. End If
  48. End Select
  49. End If
  50. End Function
  52. ' Called on Right Click up
  53. Function Object_OnRButtonUpEx(obj,x,y,dragged)
  54. If Not dragged Then
  55. Select Case obj.name
  56. Case oFldr
  57. Call resetSettings
  58. End Select
  59. End If
  60. End Function
  62. Function filefldrCheck
  63. DesktopX.Object(oBase).Picture=Object.PersistStorage("objIcon")
  64. Set oFSO = CreateObject("Scripting.FileSystemObject")
  65. 'Loads "objShortuct" Persist Storage variable
  66. oShorcut=Object.PersistStorage("objShortcut")
  67. oIcon=Object.PersistStorage("objIcon")
  68. If oIcon="" Then oIcon="red.png"
  69. DesktopX.Object(oBase).Picture=oIcon
  70. If oFSO.GetExtensionName(oShorcut) = "" Then
  71. DesktopX.Object(oFldr).Command=oShorcut
  72. DesktopX.Object(oBase).ToolTipText=oFSO.GetBaseName(oShorcut)
  73. oCommand=2
  74. Else
  75. DesktopX.Object(oFile).Command=oShorcut
  76. DesktopX.Object(oBase).ToolTipText=oFSO.GetBaseName(oShorcut)
  77. oCommand=1
  78. End If
  79. If oCommand = 2 Then
  80. DesktopX.Object(oFldr).Visible = True
  81. DesktopX.Object(oFldr).OnTop
  82. Exit Function
  83. End If
  84. Set oFSO = nothing
  85. End Function
  87. 'Called when the script is executed
  88. Sub Object_OnScriptEnter
  89. Call filefldrCheck
  90. End Sub
  92. 'Cleans up items when executed
  93. Sub cleanup
  94. With DesktopX
  95. .Object(oFldr).Command=""
  96. .Object(oFile).Command=""
  97. .Object(oBase).ToolTipText=""
  98. .Object(oBase).Picture="red.png" 'This should be your default image
  99. .Object(oFldr).Visible = False
  100. End With
  101. End Sub
  103. 'Resets & Clears settings when executed
  104. Sub resetSettings
  105. DesktopX.Object(oFldr).Visible = False
  106. DesktopX.Object(oBase).Picture="red.png" 'This should be your default image
  107. oCommand=""
  108. Object.PersistStorage("objIcon")=""
  109. Object.PersistStorage("objShortcut") = ""
  110. End Sub
  112. 'Called when the script is terminated
  113. Sub Object_OnScriptExit
  114. Call cleanup
  115. End Sub
Reply #20 from WinCustomize Forums Top
you all are doing some great stuff here.. love it!
Reply #21 from Stardock Forums Top

I believe there is a typographcial error in the Case statement for the left click function above:

Case "oBase"

The quotes refer to a variable rather than the literal expression. Removing the quotes allows the left click to function properly:

Case oBase


-Dave-